#!/usr/bin/perl -w
#
# download-block
# John Simpson <jms1@jms1.net> 2007-07-30
#
# Generates HTML for the "download blocks" I use on my web site. The idea is
# to run this script, and then copy and paste the output into the HTML file
# where the download block will appear.
#
# See http://www.jms1.net/code/ for details and to download any updates.
#
# This script updated: 2008-08-07
#
###############################################################################
#
# Copyright (C) 2007,2008 John Simpson.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License, version 3, as
# published by the Free Software Foundation.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#
###############################################################################

require 5.003 ;
use strict ;

use Getopt::Std ;

my ( %opt ) ;

sub comma($)
{
	my $x = reverse $_[0] ;
	$x =~ s/(\d\d\d)(?=\d)(?!\d*\.)/$1,/g ;
	return scalar reverse $x ;
}

sub usage()
{
	die <<EOF ;
$0 [-p] [-q] [-w] file [...]

Generates HTML code for a file download block. If multiple files are listed,
generates an outer table enclosing the download blocks for each individual
file.

For each file, a PGP signature will be checked and/or generated. These
signatures will be found or created in "filename.asc" files. Any signatures
created will use your default signing key. If the "filename.asc" file does
not contain a valid signature, the "PGP Signature" portion of the HTML
block for that file will be skipped.

-p causes the program to make sure the files are world-readable, by doing a
   "chmod 644" on the file, and also on the PGP signature file if the HTML
   link to it is being generated. This is useful if the files are already
   in a web site's document area.

-q causes the program not to generate any output other than the HTML. This
   means it won't try to create a PGP signature if one doesn't already exist.

-w generates the outer enclosing table even if only one file is listed.

EOF

}

###############################################################################
###############################################################################
###############################################################################

getopts ( "pqw" , \%opt ) ;

my $file = ( shift || usage() ) ;

my @output = () ;
my $fcount = 0 ;

while ( $file )
{
	die "ERROR: \"$file\" does not exist or is not a file.\n"
		unless ( -f $file ) ;

	if ( $file =~ /\.asc$/ )
	{
		$opt{"q"} || print "Skipping $file\n\n" ;
		$file = ( shift || "" ) ;
		next ;
	}

	$opt{"q"} || print "Processing $file\n" ;

	if ( $opt{"p"} )
	{
		$opt{"q"} || print "  Setting permissions\n" ;
		chmod ( 0644 , $file ) ;
	}

	$fcount ++ ;

	my $size = -s $file ;
	my $qsize = comma ( $size ) ;

	chomp ( my $md5sum = `openssl md5 '$file'` ) ;
	$md5sum =~ s|^.*\= ||s ;

	chomp ( my $sha1sum = `openssl sha1 '$file'` ) ;
	$sha1sum =~ s|^.*\= ||s ;

	chomp ( my $rmd160sum = `openssl rmd160 '$file'` ) ;
	$rmd160sum =~ s|^.*\= ||s ;

	my $sigblock = "" ;

	if ( ! ( $opt{"q"} || -f "$file.asc" ) )
	{
		print "  Generating PGP signature\n\n> gpg -ab $file\n" ;
		system "gpg -ab $file" ;
	}

	if ( -f "$file.asc" )
	{
		$opt{"q"} || print "  Verifying PGP signature\n" ;
		my $z = `gpg -qv $file.asc 2>&1` ;
		if ( $z =~ /Good signature/s )
		{
			$sigblock = <<EOF ;
  <tr valign="top">
    <td align="right">PGP Signature:</td>
    <td align="left"><a href="$file.asc">$file.asc</a></td>
  </tr>
EOF

			if ( $opt{"p"} )
			{
				$opt{"q"} || print "  Setting permissions on $file.asc\n" ;
				chmod ( 0644 , "$file.asc" ) ;
			}
		}
		else
		{
			$opt{"q"} || print "  WARNING: $file.asc does not contain a valid signature.\n" ;
		}
	}
	else
	{
		$opt{"q"} || print "  WARNING: cannot create PGP signature.\n" ;
	}

	$opt{"q"} || print "  Generating HTML\n\n" ;

	my $text = <<EOF ;
<table border="0" cellpadding="0" cellspacing="3" style="border: 1px solid">
  <tr valign="top">
    <td align="right">File:</td>
    <td align="left"><a href="$file">$file</a></td>
  </tr>
  <tr valign="top">
    <td align="right">Size:</td>
    <td align="left">$qsize bytes</td>
  </tr>
  <tr valign="top">
    <td align="right">Date:</td>
    <td align="left"><!--#config timefmt="%Y-%m-%d %H:%M:%S %z" --><!--#flastmod virtual="$file" --></td>
  </tr>
  <tr valign="top">
    <td align="right">MD5:</td>
    <td align="left"><tt>$md5sum</tt></td>
  </tr>
  <tr valign="top">
    <td align="right">SHA-1:</td>
    <td align="left"><tt>$sha1sum</tt></td>
  </tr>
  <tr valign="top">
    <td align="right">RIPEMD-160:</td>
    <td align="left"><tt>$rmd160sum</tt></td>
  </tr>
$sigblock</table>
EOF

	push ( @output , $text ) ;

	$file = ( shift || "" ) ;
}

$opt{"q"} || print "=" x 70 , "\n\n" ;

if ( $opt{"w"} || ( $fcount > 1 ) )
{
	print <<EOF ;
<table border="0" cellpadding="0" cellspacing="3">
EOF

	for my $text ( @output )
	{
		$text =~ s|^(\<table.+?)\>|$1 width="100%">|m ;
		$text =~ s|^|      |gm ;

		print <<EOF ;
  <tr>
    <td>

$text
    </td>
  </tr>
EOF
	}

	print <<EOF ;
</table>
EOF

	exit 0 ;
}

map { print "$_\n" } @output ;