#!/usr/bin/perl -w
#
# email-mrtg
# John Simpson <jms1@jms1.net> 2007-08-28
#
# Sends an HTML email which shows what the indicated MRTG web page would
# look like if viewed in a browser.
#
###############################################################################
#
# Copyright (C) 2007 John Simpson.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License, version 3, as
# published by the Free Software Foundation.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#
###############################################################################

require 5.003 ;
use strict ;

use MIME::Base64 ;

my $dir		= "/var/www/html/mrtg" ;
my $url		= "https://domain.xyz/mrtg" ;
my $sender	= "Admin <postmaster\@domain.xyz>" ;
my $recip	= "Admin <postmaster\@domain.xyz>" ;

###############################################################################
#
# read a file from the disk

sub readfile($)
{
	my $file = shift ;
	my $rv = "" ;

	open ( R , "<$file" ) or die "Can\'t read $file: $!\n" ;
	local($/) = undef ; # slurp
	$rv = <R> ;
	close R ;

	return $rv ;
}

###############################################################################
#
# get the base64-encoded version of a file from the disk

sub readfile_base64($)
{
	return encode_base64 ( readfile ( $_[0] ) ) ;
}

###############################################################################
#
# forward the message as an attachment

sub send_mrtg_page($)
{
	my $base = shift ;
	my $ts = sprintf ( "%08x" , time() ) ;

	my $text	= readfile        ( "$dir/$base.html"      ) ;
	my $b64_day	= readfile_base64 ( "$dir/$base-day.png"   ) ;
	my $b64_week	= readfile_base64 ( "$dir/$base-week.png"  ) ;
	my $b64_month	= readfile_base64 ( "$dir/$base-month.png" ) ;
	my $b64_year	= readfile_base64 ( "$dir/$base-year.png"  ) ;
	my $b64_ml	= readfile_base64 ( "$dir/mrtg-l.png"      ) ;
	my $b64_mm	= readfile_base64 ( "$dir/mrtg-m.png"      ) ;
	my $b64_mr	= readfile_base64 ( "$dir/mrtg-r.png"      ) ;

	$text =~ s|($base\-day\.png)|cid:$ts.$1|gi ;
	$text =~ s|($base\-week\.png)|cid:$ts.$1|gi ;
	$text =~ s|($base\-month\.png)|cid:$ts.$1|gi ;
	$text =~ s|($base\-year\.png)|cid:$ts.$1|gi ;
	$text =~ s|(mrtg\-l\.png)|cid:$ts.$1|gi ;
	$text =~ s|(mrtg\-m\.png)|cid:$ts.$1|gi ;
	$text =~ s|(mrtg\-r\.png)|cid:$ts.$1|gi ;

	my $sep = sprintf ( "mime.%s.%04X.separator" , $ts , $$ ) ;

	my $now = localtime() ;

	open ( O , "| /var/qmail/bin/qmail-inject" )
		or die "Can\'t run /var/qmail/bin/qmail-inject: $!\n" ;

	print O <<EOF ;
Date: $now
From: $sender
To: $recip
Subject: MRTG $base
MIME-Version: 1.0
Content-Type: multipart/related; boundary="$sep"

If you are seeing this, your MUA (Mail User Agent, the program with which
you read and compose email) does not properly handle MIME (Multipurpose
Internet Mail Extensions, RFC 2045-2049), or is showing you this "preamble"
as a courtesy.

If your MUA doesn't handle MIME, you will see a bunch of HTML below, and
then seven blocks of seemingly random text. This normally all fits together
to produce an email which looks like the MRTG page you are being sent,
however the HTML code and base64-encoded images probably don't look as nice
when you're seeing the raw source. You can see the actual web page at this
address:

$url/$base.html

The code below may or may not produce a link that you can click to jump
directly to the web page in a browser:

<a href="$url/$base.html">$url/$base.html</a>

--$sep
Content-Type: text/html
Content-Transfer-Encoding: 7bit

$text
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="$base-day.png"
Content-ID: <$ts.$base-day.png>

$b64_day
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="$base-week.png"
Content-ID: <$ts.$base-week.png>

$b64_week
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="$base-month.png"
Content-ID: <$ts.$base-month.png>

$b64_month
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="$base-year.png"
Content-ID: <$ts.$base-year.png>

$b64_year
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="mrtg-l.png"
Content-ID: <$ts.mrtg-l.png>

$b64_ml
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="mrtg-m.png"
Content-ID: <$ts.mrtg-m.png>

$b64_mm
--$sep
Content-Type: image/png
Content-Transfer-Encoding: base64
Content-Disposition: inline; filename="mrtg-r.png"
Content-ID: <$ts.mrtg-r.png>

$b64_mr
--$sep--
EOF

	close O ;
}

###############################################################################

sub usage()
{
	die <<EOF ;
$0 filename [...]

    filename	should be the names of one or more web pages within the
		configured MRTG directory and/or web site.

Configuration:
  URL:		$url
  Directory:	$dir

EOF
}

###############################################################################
###############################################################################
###############################################################################

$dir =~ s|/$|| ;
$url =~ s|/$|| ;

die "ERROR: Please configure the script before running it.\n"
	if (    ( $sender =~ m|\@domain\.xyz|  )
	     || ( $recip  =~ m|\@domain\.xyz|  )
	     || ( $url    =~ m|//domain\.xyz/| ) ) ;

my $name = ( shift || usage() ) ;

while ( $name )
{
	$name =~ s|.*/|| ;
	$name =~ s|\.html$|| ;

	die "ERROR: \"$dir/$name.html\" does not exist\n"
		unless ( -f "$dir/$name.html" ) ;

	send_mrtg_page ( $name ) ;

	$name = ( shift || "" ) ;
}