#!/usr/bin/perl -w
#
# epw
# John Simpson <jms1@jms1.net> 2006-11-26
#
# quick and dirty script to print out encrypted passwords
#
###############################################################################
#
# Copyright (C) 2006 John Simpson.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License, version 2, as
# published by the Free Software Foundation.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
# or visit http://www.gnu.org/licenses/gpl.txt
#
###############################################################################

require 5.003 ;
use Crypt::PasswdMD5 ;
use Getopt::Std ;

###############################################################################

sub usage()
{
	print <<EOF ;
$0 [options] password

Prints the encrypted version of a given plain-text password.

Options:
  -m
      Use the newer MD5 algorithm (default.)

  -u
      Use the old unix crypt() algorithm instead of MD5.

  -s salt
      Manually specify the salt value. This should be (2 for crypt(), 8 for
      MD5) bytes, chosen from the set ( ".", "/", 0-9, "A"-"Z", "a"-"z" ).

EOF
	exit 0 ;
}

###############################################################################

my $saltc = join ( "" , ( "./" , 0..9 , "A".."Z" , "a".."z" ) ) ;

sub mksalt(;$)
{
	my $len = ( shift || 8 ) ;
	my $rv = "" ;

	while ( $len -- )
	{
		$rv .= substr ( $saltc , int rand 64 , 1 ) ;
	}

	return $rv ;
}

sub saltok($)
{
	for my $c ( split ( // , $_[0] ) )
	{
		return 0 if ( $saltc !~ /$c/x ) ;
	}

	return 1 ;
}

###############################################################################
###############################################################################
###############################################################################

our ( $opt_s , $opt_u , $opt_m ) ;
my $md5 = 1 ;

###############################################################################
#
# are we doing crypt() or MD5?

getopts ( "s:um" ) ;

$md5 = ( $opt_u ? ( $opt_m ? 1 : 0 ) : 1 ) ;

###############################################################################
#
# get salt, either from command line or from mksalt()

my $slen = $md5 ? 8 : 2 ;
my $salt = "" ;

$salt = ( $opt_s || mksalt ( $slen ) ) ;

if ( length ( $salt ) != $slen )
{
	die ( "ERROR: salt should be $slen bytes for "
		. ( $md5 ? "MD5" : "crypt()" ) . " encryption.\n" ) ;
}

die "ERROR: invalid characters in salt, use only these:\n$saltc\n"
	unless ( saltok ( $salt ) ) ;

###############################################################################
#
# get plain-text password from command line

my $ppw = ( shift || usage() ) ;

###############################################################################
#
# do it

if ( $md5 )
{
	print unix_md5_crypt ( $ppw , $salt ) , "\n" ;
}
else
{
	print crypt ( $ppw , $salt ) , "\n" ;
}